Заметки по SQL: Срез последних - аналог запроса

Публикация № 980323

Программирование - Практика программирования

14
В статье описывается создание среза последних данных средствами классического языка запросов. Причем метод построения запроса был разработан еще во времена, когда автор работал с СУБД Oracle 9i и программировал на PL SQL. Основная идея заключается преобразовании запроса с подзапросом, в запрос без подзапроса (в примерах описывается преобразование до двух вложенных подзапросов). Запросы тестировались на реальных базах данных. Платформа - 1С:Предприятие 8.3 (8.3.10.2561).

1. Введение

Поскольку я занимаюсь сопровождением конфигурации - "Расчеты с населением за газ" (разработчик - ООО "АНТ-Консалт"), внедренной в 56 регионах России (цифра приблизительная), то все примеры будут основаны на данных именно этой конфигурации. Основу примеров составят запросы к регистру сведений "ПоказанияСчетчиков".

Вид запроса 1с для периодического, независимого регистра сведений с периодичностью "В пределах секунды",  который реально формируется в СУБД выглядит следующим образом:

ВЫБРАТЬ
	ВложенныйЗапрос.Оборудование КАК Оборудование,
	ВложенныйЗапрос.ПоследниеПоказанияПериод КАК ПоследниеПоказанияПериод,
	ПКУ_ПоказанияСчетчиков.Значение КАК ПоследниеПоказанияЗначение
ИЗ
	(ВЫБРАТЬ
		ПКУ_ПоказанияСчетчиков.Оборудование КАК Оборудование,
		МАКСИМУМ(ПКУ_ПоказанияСчетчиков.Период) КАК ПоследниеПоказанияПериод
	ИЗ
		РегистрСведений.ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
	ГДЕ
		ПКУ_ПоказанияСчетчиков.Период <= &ДатаПоказаний
	
	СГРУППИРОВАТЬ ПО
		ПКУ_ПоказанияСчетчиков.Оборудование) КАК ВложенныйЗапрос
		ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
		ПО ВложенныйЗапрос.Оборудование = ПКУ_ПоказанияСчетчиков.Оборудование
			И ВложенныйЗапрос.ПоследниеПоказанияПериод = ПКУ_ПоказанияСчетчиков.Период

Для простоты понимания пример приведен в синтаксисе языка запросов 1с, как реально это может выглядеть в profiler на MS SQL можно посмотреть в очень популярной статье на Инфостарте - "Регистры сведений 1С. Как это устроено.", раздел "3. Как работает СрезПоследних (СрезПервых) в запросе". 

А теперь преобразуем запрос с подзапросом в один запрос;

ВЫБРАТЬ
	ПКУ_ПоказанияСчетчиков.Значение КАК ПоследниеПоказанияЗначение,
	ПКУ_ПоказанияСчетчиков.Оборудование КАК Оборудование,
	ПКУ_ПоказанияСчетчиков.Период КАК Период
ИЗ
	РегистрСведений.ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков1
		ПО ПКУ_ПоказанияСчетчиков.Оборудование = ПКУ_ПоказанияСчетчиков1.Оборудование
ГДЕ
	ПКУ_ПоказанияСчетчиков.Период <= &ДатаПоказаний

СГРУППИРОВАТЬ ПО
	ПКУ_ПоказанияСчетчиков.Оборудование,
	ПКУ_ПоказанияСчетчиков.Значение,
	ПКУ_ПоказанияСчетчиков.Период

ИМЕЮЩИЕ
	МАКСИМУМ(ПКУ_ПоказанияСчетчиков1.Период) = ПКУ_ПоказанияСчетчиков.Период

Как видим нет ничего сверх естественного, все в рамках классического  SQL. Даже и пояснять особо ничего не нужно. Отмечу, что эта конструкция, будет являться базовой для построения запросов следующей публикации.

2. Работа с реальными данными.

Мы разобрали простейший пример, но не все так просто с реальными данными. В конфигурации для регистра сведений "ПоказанияСчетчиков" установлена периодичность "По позиции регистратора" , более того добавлен реквизит "ДатаРегистрацииИзменения". Спросим разработчиков, для чего введен этот реквизит, и услышим ответ, в конфигурации присутствуют данные, когда период и регистратор совпадают. А это значит, что запрос функция 1с :

ВЫБРАТЬ
	ПринятыеКУчетуПоказанияСрезПоследних.Период КАК Период,
	ПринятыеКУчетуПоказанияСрезПоследних.Оборудование КАК Оборудование,
	ПринятыеКУчетуПоказанияСрезПоследних.Значение КАК Значение
ИЗ
	РегистрСведений.ПринятыеКУчетуПоказания.СрезПоследних(, НЕ НеПриниматьКУчету) КАК ПринятыеКУчетуПоказанияСрезПоследних

работать будет не правильно.

Что же нам предлагают разработчики конфигурации - текст запроса:

ВЫБРАТЬ
	ПоказанияСчетчиков.Оборудование КАК Оборудование,
	ПоказанияСчетчиков.Значение КАК Значение,
	ПоказанияСчетчиков.ДатаРегистрацииИзменения КАК ДатаРегистрацииИзменения,
	ПоказанияСчетчиков.НеПриниматьКУчету КАК НеПриниматьКУчету,
	ПоказанияСчетчиков.Период КАК Период,
	ПоказанияСчетчиков.Регистратор КАК Регистратор
ПОМЕСТИТЬ втНач
ИЗ
	РегистрСведений.ПоказанияСчетчиков КАК ПоказанияСчетчиков
ГДЕ
	ПоказанияСчетчиков.Период <= &ДатаПоказаний

ИНДЕКСИРОВАТЬ ПО
	ПоказанияСчетчиков.Оборудование,
	ПоказанияСчетчиков.Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	втНач.Оборудование КАК Оборудование,
	втНач.Значение КАК Значение,
	втНач.Период КАК Период
ПОМЕСТИТЬ ПКУ_ПоказанияСчетчиков
ИЗ
	втНач КАК втНач
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
			втНач.Оборудование КАК Оборудование,
			МАКСИМУМ(втНач.Регистратор) КАК Регистратор,
			втНач.Период КАК Период,
			втНач.ДатаРегистрацииИзменения КАК ДатаРегистрацииИзменения
		ИЗ
			втНач КАК втНач
				ВНУТРЕННЕЕ СОЕДИНЕНИЕ (ВЫБРАТЬ
					втНач.Оборудование КАК Оборудование,
					втНач.Период КАК Период,
					МАКСИМУМ(втНач.ДатаРегистрацииИзменения) КАК ДатаРегистрацииИзменения
				ИЗ
					втНач КАК втНач
				
				СГРУППИРОВАТЬ ПО
					втНач.Оборудование,
					втНач.Период) КАК втДни2
				ПО втНач.Период = втДни2.Период
					И втНач.ДатаРегистрацииИзменения = втДни2.ДатаРегистрацииИзменения
					И втНач.Оборудование = втДни2.Оборудование
		
		СГРУППИРОВАТЬ ПО
			втНач.Оборудование,
			втНач.Период,
			втНач.ДатаРегистрацииИзменения) КАК втДни
		ПО втНач.Период = втДни.Период
			И втНач.ДатаРегистрацииИзменения = втДни.ДатаРегистрацииИзменения
			И втНач.Регистратор = втДни.Регистратор
			И втНач.Оборудование = втДни.Оборудование
ГДЕ
	НЕ втНач.НеПриниматьКУчету

ИНДЕКСИРОВАТЬ ПО
	втНач.Оборудование,
	втНач.Период
;

////////////////////////////////////////////////////////////////////////////////
УНИЧТОЖИТЬ втНач
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ВложенныйЗапрос.Оборудование КАК Оборудование,
	ВложенныйЗапрос.ПоследниеПоказанияПериод КАК ПоследниеПоказанияПериод,
	ПКУ_ПоказанияСчетчиков.Значение КАК ПоследниеПоказанияЗначение
ИЗ
	(ВЫБРАТЬ
		ПКУ_ПоказанияСчетчиков.Оборудование КАК Оборудование,
		МАКСИМУМ(ПКУ_ПоказанияСчетчиков.Период) КАК ПоследниеПоказанияПериод
	ИЗ
		ПКУ_ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
	
	СГРУППИРОВАТЬ ПО
		ПКУ_ПоказанияСчетчиков.Оборудование) КАК ВложенныйЗапрос
		ЛЕВОЕ СОЕДИНЕНИЕ ПКУ_ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
		ПО ВложенныйЗапрос.Оборудование = ПКУ_ПоказанияСчетчиков.Оборудование
			И ВложенныйЗапрос.ПоследниеПоказанияПериод = ПКУ_ПоказанияСчетчиков.Период

Ну что ж, вполне себе работоспособный запрос . При чем вторая временная таблица "ПКУ_ПоказанияСчетчиков", очень напоминает нам аналог конструкции для регистра с периодичностью "По позиции регистратора" в СУБД, с той лишь разницей, что вместо периода используется реквизит "ДатаРегистрацииИзменения". Пример можно увидеть в уже вышеупомянутой статье - "Регистры сведений 1С. Как это устроено.", раздел "3. Как работает СрезПоследних (СрезПервых) в запросе".  Этот запрос был использован при разработке отчета в публикации "Реестр показаний по приборам учета за период с расчетом среднего потребления ресурса"

А теперь самое интересное. Преобразуем этот запрос, в запрос с одной виртуальной таблицей без подзапросов. Код запроса:

ВЫБРАТЬ
	втНач.Оборудование КАК Оборудование,
	втНач.Период КАК Период,
	втНач.Значение КАК Значение
ПОМЕСТИТЬ ПКУ_ПоказанияСчетчиков
ИЗ
	РегистрСведений.ПоказанияСчетчиков КАК втНач
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПоказанияСчетчиков КАК втНач1
		ПО втНач.Оборудование = втНач1.Оборудование
			И втНач.Период = втНач1.Период
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ПоказанияСчетчиков КАК втНач2
		ПО втНач.Оборудование = втНач2.Оборудование
			И втНач.Период = втНач2.Период
ГДЕ
	НЕ втНач.НеПриниматьКУчету
	И втНач.Период <= &ДатаПоказаний

СГРУППИРОВАТЬ ПО
	втНач.Оборудование,
	втНач.Период,
	втНач.Регистратор,
	втНач.ДатаРегистрацииИзменения,
	втНач1.ДатаРегистрацииИзменения,
	втНач.Значение

ИМЕЮЩИЕ
	МАКСИМУМ(втНач2.ДатаРегистрацииИзменения) = втНач1.ДатаРегистрацииИзменения И
	МАКСИМУМ(втНач1.Регистратор) = втНач.Регистратор

ИНДЕКСИРОВАТЬ ПО
	Оборудование,
	Период
;

////////////////////////////////////////////////////////////////////////////////
ВЫБРАТЬ
	ПКУ_ПоказанияСчетчиков.Оборудование КАК Оборудование,
	ПКУ_ПоказанияСчетчиков.Период КАК Период,
	ПКУ_ПоказанияСчетчиков.Значение КАК ПоследниеПоказанияЗначение
ИЗ
	ПКУ_ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ ПКУ_ПоказанияСчетчиков КАК ПКУ_ПоказанияСчетчиков1
		ПО ПКУ_ПоказанияСчетчиков.Оборудование = ПКУ_ПоказанияСчетчиков1.Оборудование

СГРУППИРОВАТЬ ПО
	ПКУ_ПоказанияСчетчиков.Оборудование,
	ПКУ_ПоказанияСчетчиков.Значение,
	ПКУ_ПоказанияСчетчиков.Период

ИМЕЮЩИЕ
	МАКСИМУМ(ПКУ_ПоказанияСчетчиков1.Период) = ПКУ_ПоказанияСчетчиков.Период

     Немного анализа с аналогиями. Как видим первое соединение с втНач1, есть аналог первого подзапроса разработчиков конфигурации, второй виртуальной таблицы "ПКУ_ПоказанияСчетчиков" с условием  втНач.ДатаРегистрацииИзменения = втДни2.ДатаРегистрацииИзменения, только у нас условие  МАКСИМУМ(втНач1.ДатаРегистрацииИзменения) = втНач.ДатаРегистрацииИзменения. Естественно это соединение выполняется первым. И соответственно второй подзапрос имеющий свой подзапрос соединяющийся условием втНач.Регистратор = втДни.Регистратор, соответствует условию нашего запроса МАКСИМУМ(втНач2.Регистратор) = втНач.Регистратор второго соединения с регистром сведений ПоказанияСчетчиков втНач2. Ну, а с выходным запросом мы уже познакомились во введении к данной статье.

     Поскольку здесь сравниваются два запроса по реальным данным, уместно будет привести данные по их быстродействию. Так вот, первый запрос работает медленнее чем предложенный вариант приблизительно на 25% (обрабатывается 105 566 записей), при первом запуске в консоли запросов (не кешируемые запросы). Причем при повторном запуске (кешируемые запросы),  разность в скорости выполнения достигает порядка 50%, то есть предложенный вариант лучше кешируется, за счет отсутствия вложенных запросов. База данных расположена на MS SQL сервере.

    Таким образом получено реальное улучшение быстродействия запроса, в случае когда стандартными средствами 1с (виртуальными таблицами, срез последних) корректно решить задачу не не удалось.

3. Формализация результата

Исходя из выше изложенного материала, можно предложить формализованную методику построения запроса получения среза последних данных произвольной глубины вложенности.

 
 
ВЫБРАТЬ
	втНач.ПолеОдин КАК ПолеОдин,
	втНач.ПолеДва КАК ПолеДва,
	втНач.Период КАК Период
ПОМЕСТИТЬ ВремТабл
ИЗ
	РегистрСведений.ДанныеРегистра КАК втНач
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ДанныеРегистра КАК втНач(1)
		ПО втНач.ПолеОдин = втНач(1).ПолеОдин
		 И втНач.ПолеДва = втНач(1).ПолеДва
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ДанныеРегистра КАК втНач(2)
		ПО  втНач(1).ПолеОдин = втНач(2).ПолеОдин
		  И втНач(1).ПолеДва = втНач(2).ПолеДва
		...............................................................
		ВНУТРЕННЕЕ СОЕДИНЕНИЕ РегистрСведений.ДанныеРегистра КАК втНач(N)
		ПО втНач(N-1).ПолеОдин = втНач(N).ПолеОдин
		 И втНач(N-1).ПолеДва = втНач(N).ПолеДва
			
ГДЕ
	втНач.Период <= &ДатаПолучения

СГРУППИРОВАТЬ ПО
	втНач.ПолеОдин,
	втНач.ПолеДва,
	втНач.Период,
	втНач.ПериродическийРеквизит,
	втНач(1).ПериродическийРеквизит(1),
	...................................
	втНач(N-1).ПериродическийРеквизит(N)
	
ИМЕЮЩИЕ
	МАКСИМУМ(втНач(1).ПериродическийРеквизит(1)) = втНач.ПериродическийРеквизит
	МАКСИМУМ(втНач(2).ПериродическийРеквизит(2)) = втНач(1).ПериродическийРеквизит(1) И
	................................................................................
	МАКСИМУМ(втНач(N).ПериродическийРеквизит(N)) = втНач(N-1).ПериродическийРеквизит(N) 

 

 

 

14

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. Batman 149 16.01.19 12:25 Сейчас в теме
"...автор работал с СУБД Orakle 9i" - опечатка?
2. Fox-trot 99 16.01.19 12:40 Сейчас в теме
видимо настолько это давно было, что забыл как пишется
3. IVC_goal 82 16.01.19 13:33 Сейчас в теме
Виноват исправлю. А было это 9 лет назад
4. laby 23.01.19 10:35 Сейчас в теме
ничего не понятно, зачем куча вложенных запросов. В первом пункте ещё как-то понятно, а пункт два - это что-то с чем-то ...
conductor; +1 Ответить
5. IVC_goal 82 23.01.19 11:04 Сейчас в теме
(4) Первый вложенный запрос отбирает последние введенные показания по ДатаРегистрацииИзменения. Второй вложенный запрос отбирает последний документ регистрации для введенных показаний на ДатаРегистрацииИзменения. И последний запрос отбирает последний период, когда были введены показания.
Оставьте свое сообщение